Excel导出出现0x800A03EC错误但功能正常，求原因分析

• 程序运行流程：
  1. 用户选择需要标准化的Excel文件；
  2. 列排序完成后点击“Export”按钮，列标题自动替换为StandardColumnOrder中的内容，随后复制所需数据。
• 异常情况：选择列标题与预期不符的文件时，弹出错误代码0x800A03EC，但最终生成的Excel文件无异常，程序功能仍正常。

Private Sub BtnExport_Click(sender As Object, e As EventArgs) Handles BtnExport.Click
    Try
        ' Percorso del file di destinazione
        Dim famiglieDiScontoPath As String = iniFile.ReadValue("Percorsi", "FamiglieDiSconto")
        Dim xlNewApp As New Application()
        Dim xlNewWorkbook As Workbook
        Dim xlNewWorksheet As Worksheet
        Dim fileExists As Boolean = System.IO.File.Exists(famiglieDiScontoPath)

        ' Se il file esiste, aprilo; altrimenti creane uno nuovo
        If System.IO.File.Exists(famiglieDiScontoPath) Then
            ' Apri il file esistente SENZA mostare finestre di conferma
            xlNewWorkbook = xlNewApp.Workbooks.Open(famiglieDiScontoPath, [ReadOnly]:=False, [Editable]:=True)
        Else
            ' Crea un nuovo file se non esiste
            xlNewWorkbook = xlNewApp.Workbooks.Add()
        End If

        ' Ottieni il foglio "Famiglie Di Sconto"
        Try
            xlNewWorksheet = xlNewWorkbook.Sheets("Famiglie Di Sconto")
        Catch ex As Exception
            ' Se il foglio non esiste, crealo
            xlNewWorksheet = xlNewWorkbook.Sheets(1)
            xlNewWorksheet.Name = "Famiglie Di Sconto"
        End Try

        ' **1. Recupera combinazioni esistenti nel file di destinazione**
        Dim existingEntries As New HashSet(Of String)
        Dim lastExistingRow As Integer = xlNewWorksheet.Cells(xlNewWorksheet.Rows.Count, 1).End(XlDirection.xlUp).Row
        If lastExistingRow < 2 Then lastExistingRow = 1 ' Assicura che parta da riga 2 in poi

        For rowIndex As Integer = 2 To lastExistingRow
            Dim existingCodiceUnivoco As String = xlNewWorksheet.Cells(rowIndex, 1).Value
            Dim existingSconto As String = xlNewWorksheet.Cells(rowIndex, 2).Value
            Dim existingPrezzo As String = xlNewWorksheet.Cells(rowIndex, 3).Value
            If Not String.IsNullOrEmpty(existingCodiceUnivoco) And Not String.IsNullOrEmpty(existingSconto) Then
                existingEntries.Add(existingCodiceUnivoco & "_" & existingSconto & "_" & existingPrezzo)
            End If
        Next

        ' **2. Trova la prima riga disponibile per i nuovi dati**
        Dim nextRow As Integer = lastExistingRow + 1
        ' **3. Creiamo un HashSet per nuovi dati da copiare**

        Dim uniqueEntries As New HashSet(Of String)
        ' Trova gli indici delle colonne nel file originale

        Dim codiceUnivocoIndex As Integer = columnHeaders.IndexOf("Codice Univoco Azienda") + 1
        Dim scontoIndex As Integer = columnHeaders.IndexOf("Sconto") + 1
        Dim prezzoIndex As Integer = columnHeaders.IndexOf("Prezzo") + 1

        ' **4. Scansiona il file di origine e copia solo nuove combinazioni**
        For rowIndex As Integer = headerRow + 1 To xlWorksheet.UsedRange.Rows.Count
            Dim codiceUnivocoValue As String = xlWorksheet.Cells(rowIndex, codiceUnivocoIndex).Value
            Dim scontoValue As String = xlWorksheet.Cells(rowIndex, scontoIndex).Value
            Dim prezzoValue As String = xlWorksheet.Cells(rowIndex, prezzoIndex).Value
            Dim entryKey As String = codiceUnivocoValue & "_" & scontoValue & "_" & prezzoValue

            ' Se la combinazione non è già presente nel file di destinazione, aggiungila
            If Not existingEntries.Contains(entryKey) And Not uniqueEntries.Contains(entryKey) Then
                uniqueEntries.Add(entryKey)
                xlNewWorksheet.Cells(nextRow, 1).Value = codiceUnivocoValue ' "Codice Univoco Azienda" in colonna A
                xlNewWorksheet.Cells(nextRow, 2).Value = scontoValue ' "Sconto" in colonna B
                xlNewWorksheet.Cells(nextRow, 3).Value = prezzoValue ' "Prezzo" in colonna C
                nextRow += 1
            End If
        Next

        ' **5. Salva e chiudi il file di destinazione**
        xlNewWorkbook.Save()
        xlNewWorkbook.Close(SaveChanges:=True)
        xlNewApp.Quit()

        ' **Rilascia le risorse**
        ReleaseObject(xlNewWorksheet)
        ReleaseObject(xlNewWorkbook)
        ReleaseObject(xlNewApp)

    Catch ex As Exception
        MessageBox.Show($"Errore durante l'esportazione: {ex.Message}", "Errore", MessageBoxButtons.OK, MessageBoxIcon.Error)
    End Try

    Try
        ' Verifica che gli oggetti Excel siano inizializzati
        If xlApp Is Nothing OrElse xlWorkbook Is Nothing OrElse xlWorksheet Is Nothing Then
            MessageBox.Show("Non c'è un file Excel aperto. Apri un file prima di esportare.", "Errore", MessageBoxButtons.OK, MessageBoxIcon.Warning)
            Return
        End If

        ' Verifica che un codice sia stato selezionato nella ComboBox
        Dim selectedCodice As String = ComboBoxCodici.SelectedItem?.ToString()

        If String.IsNullOrEmpty(selectedCodice) Then
            MessageBox.Show("Seleziona un codice univoco dalla ComboBox prima di esportare.", "Errore", MessageBoxButtons.OK, MessageBoxIcon.Warning)
            Return
        End If

        ' Esporta i dati in un nuovo file Excel
        SaveFileDialog1.Filter = "Excel Files|*.xls;*.xlsx;*.xlsm"

        If SaveFileDialog1.ShowDialog() = DialogResult.OK Then
            Dim exportFilePath = SaveFileDialog1.FileName
            Dim newWorkbook = xlApp.Workbooks.Add()
            Dim newWorksheet = CType(newWorkbook.Sheets(1), Worksheet)
            ' Calcola il numero totale di righe da elaborare
            Dim totalRows = xlWorksheet.UsedRange.Rows.Count - headerRow
            Dim currentRow = 0

            ProgressBar1.Visible = True
            ProgressBar1.Value = 0

            ' Cambia i nomi delle colonne secondo l'ordine standard e aggiungi titoli al nuovo file
            For colIndex = 0 To ListBox1.Items.Count - 1
                Dim currentHeader As String = ""

                If colIndex < ListBox1.Items.Count Then
                    currentHeader = ListBox1.Items(colIndex).ToString()
                End If

                If Not String.IsNullOrEmpty(currentHeader) Then
                    newWorksheet.Cells(1, colIndex + 1).Value = currentHeader
                End If

                ' Usa il nome della colonna standard se necessario
                If colIndex < standardColumnOrder.Count AndAlso currentHeader <> standardColumnOrder(colIndex) Then
                    currentHeader = standardColumnOrder(colIndex)
                End If
                ' Imposta il nome della colonna nel nuovo file
                newWorksheet.Cells(1, colIndex + 1).Value = currentHeader
            Next

            ' Copia i dati ordinati dalla ListBox al nuovo foglio Excel

            For rowIndex = headerRow + 1 To xlWorksheet.UsedRange.Rows.Count
                For colIndex = 1 To ListBox1.Items.Count
                    Dim columnName = ListBox1.Items(colIndex - 1).ToString()
                    Dim originalIndex = columnHeaders.IndexOf(columnName) + 1
                    ' Copia il valore dalla colonna originale
                    Dim cellValue = If(originalIndex > 0, xlWorksheet.Cells(rowIndex, originalIndex).Value, "")
                    ' Se la colonna è "Codice Univoco Azienda", usa il valore selezionato
                    If colIndex = 5 Then
                        cellValue = selectedCodice
                    End If

                    ' Scrivi il valore nella nuova cella
                    newWorksheet.Cells(rowIndex - headerRow + 1, colIndex).Value = If(cellValue IsNot Nothing, cellValue, "")
                Next

                ' Aggiorna la barra di caricamento
                currentRow += 1
                ProgressBar1.Value = CInt((currentRow / totalRows) * 100)
                System.Windows.Forms.Application.DoEvents()
            Next

            ' Salva il nuovo file
            MessageBox.Show(exportFilePath)
            newWorkbook.SaveAs(exportFilePath)
            newWorkbook.Close()

            ' Carica i dati esportati nella GridView
            LoadExportedDataIntoGridView(exportFilePath)

            ' Aggiorna lo stato dei pulsanti
            isExported = True
            BtnUploadToDatabase.Enabled = True
            BtnExport.Enabled = False
            ProgressBar1.Visible = False
            MessageBox.Show("File esportato con successo.")
        End If
    Catch ex As Exception
        MessageBox.Show($"Errore durante l'esportazione: {ex.Message}")
        ' Non chiudere gli oggetti Excel per permettere ulteriori tentativi
    Finally
        ' Assicurati che la ProgressBar sia nascosta
        ProgressBar1.Visible = False
    End Try
End Sub

错误代码0x800A03EC是Excel Interop组件的常见错误，结合代码和场景，核心原因如下：

1. 无效列索引访问
   代码中通过columnHeaders.IndexOf("Codice Univoco Azienda") + 1获取列索引，若原文件不存在指定列，IndexOf返回-1，加1后得到0。而Excel的列索引从1开始，访问xlWorksheet.Cells(rowIndex, 0)会直接触发该错误。
   虽然后续逻辑会将空值写入目标文件，不影响最终结果，但访问无效列索引的操作本身会抛出异常，导致错误弹窗。

2. 未处理列不存在的场景
   第一个Try块中，未对codiceUnivocoIndex、scontoIndex、prezzoIndex的有效性做判断。即使这些列不存在，代码仍会尝试读取对应位置的单元格，触发Excel错误。

3. 独立Try块的影响
   按钮事件包含两个独立的Try块，第一个块处理FamiglieDiSconto文件的更新，第二个块处理用户导出的新文件。错误发生在第一个块时，会触发弹窗，但第二个块仍会正常执行，因此最终导出的文件无异常。

• 在获取列索引后，先判断是否有效（即索引>0），若无效则跳过对应列的读取逻辑，或提示用户文件格式不符。
  示例：

  Dim codiceUnivocoIndex As Integer = columnHeaders.IndexOf("Codice Univoco Azienda") + 1
  If codiceUnivocoIndex <= 0 Then
      MessageBox.Show("文件缺少必要列：Codice Univoco Azienda", "格式错误", MessageBoxButtons.OK, MessageBoxIcon.Error)
      Return
  End If
  

• 统一错误处理逻辑，避免两个独立Try块导致的异常提示与实际结果不一致的情况。

内容的提问来源于stack exchange，提问作者frency 211